『 闪 界 』 - FlashJ.cn

package org.mousebomb.dragLiToCanvas 
{
	import fl.events.ListEvent;
	import fl.controls.List;
	import fl.data.DataProvider;
 
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.utils.getDefinitionByName;
 
	/**
	 * @author Mousebomb (mousebomb@gmail.com)
	 * @date 2010-4-27
	 */
	public class DragListItemToCanvas extends Sprite 
	{
		public var list : List;
		public var canvas : Sprite;
		private var isHoverLi : Boolean = false;
		private var curHoverLi : Object ;
 
		public function DragListItemToCanvas()
		{
			//如果不写下面这一行，flash不会将此类编译进去，运行时会报错
			Class1;
			Class2;
			//创建list的内容
			list.dataProvider = new DataProvider();
			list.addItem({label:"有胆你就拖拽我", data:"org.mousebomb.dragLiToCanvas.Class1"});
			list.addItem({label:"我和楼上一样", data:"org.mousebomb.dragLiToCanvas.Class2"});
			list.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDownH);
			list.addEventListener(ListEvent.ITEM_ROLL_OVER, onHoverLi);
			list.addEventListener(ListEvent.ITEM_ROLL_OUT, onOutLi);
			stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUpH);
		}
 
		private function onOutLi(event : ListEvent) : void
		{
			isHoverLi = false;
			curHoverLi = null;
		}
 
		private function onHoverLi(event : ListEvent) : void
		{
			isHoverLi = true;
			curHoverLi = event.item;
		}
 
		//松开鼠标
		private function onMouseUpH(event : MouseEvent) : void
		{
			//有拖拽物体
			if(curDraging)
			{
				curDraging.stopDrag();
				removeChild(curDraging);
				//在canvas上着陆
				if(canvas.hitTestPoint(event.stageX, event.stageY))
				{
					canvas.addChild(curDraging);
					curDraging.alpha = 1;
					var localPos : Point = canvas.globalToLocal(new Point(event.stageX, event.stageY));
					curDraging.x = localPos.x;
					curDraging.y = localPos.y;
				}
				curDraging = null;
			}
		}
 
		//记录当前拖拽
		private var curDraging : Sprite;
 
		private function onMouseDownH(event : MouseEvent) : void
		{
			if(curHoverLi)
			{
				var className : String = curHoverLi["data"];
				curDraging = getItemByClassName(className);
				curDraging.x = event.stageX;
				curDraging.y = event.stageY;
				curDraging.alpha = .6;
				addChild(curDraging);
				curDraging.startDrag();
			}
		}
 
		//获取对应的实例
		private function getItemByClassName(className : String) : Sprite
		{
			var cla : Class = getDefinitionByName(className) as Class;
			return new cla();
		}
	}
}